Thema: Schnellbausteine

Hallo, hier zwei Fragen zu Schnellbausteinen:
Ich habe für häufig benötigte Textelemente einige Schnellbausteine erstellt und möchte diese auf Datenträger an andere Rechner mitnehmen. Wo sind die Dinger gespeichert? Kann ich mir eigene Kataloge anlegen, damit der Wirrwarr in den Bausteinen nicht zu groß wird?

Wie kann man Schnellbausteine schöner und geordneter drucken als über das Druckmenü, z. B. auch wieder nur meine eigenen Bausteine? Ich wüßte gerne eine Möglichkeit, nur ausgewählte Bausteine oder eben vorher angelegte Kategorien zu drucken.

Vielen Dank im Voraus!
Antje

Re: Schnellbausteine

Hallo Antje
ich nehme an, Du hast Word 2007.
Leider sind Bausteine für den normalen Anwender in 2007 komplizierter und unübersichtlicher geworden. Um vernünftig arbeiten zu können, musst Du zunächst etwas Zeit investieren.
Grundsätzlich: Es gibt 35 Bausteintypen (=Kataloge), Du musst einen oder mehrere davon nutzen. Du kannst keinen eigenen Bausteintyp erstellen.
Bausteine können nur in einer Dokumentvorlage gespeichert werden. Zur Weitergabe muss die Vorlage weitergegeben werden.
Ausgewählte Bausteine drucken nur mit Makro.
Empfehlung: Alle eigenen Bausteine in Dokumentvorlage „autotext.dotm“ in Katalog „Autotext“ und Kategorie „Allgemein“.

1. Registerkarte Einfügen-Gruppe Text-Schnellbausteine-Organizer für Bausteine-alle Einträge in Katalog Autotext löschen (wenn Du sie nicht brauchst)
2. Rechte Maustaste auf Menü-Symbolleiste für den Schnellzugriff unter Multifunktionsleiste (falls noch nicht gemacht)
2. Office Symbol-Word Optionen-Anpassen-Liste Befehle auswählen: oben Alle Befehle-unten Autotext, Organizer für Bausteine, Dokumentvorlage wählen und mit Hinzufügen auf Symbolleiste übertragen.
3. Leeres neues Dokument mit dem Namen „autotext.dotm“ als „Word Vorlage mit Makros“ in „Vertrauenswürdige Vorlagen“ speichern.
4. In der Vorlage einen Baustein erstellen-Markieren-Symbol Autotext auf Symbolleiste klicken-Auswahl im Autotextkatalog speichern-Namen eingeben, speichern in „autotext.dotm“ wählen-OK.
5. Alt+F11 (öffnet VBA-Editor)-im linken (schmalen) Fenster rechte Maustaste auf TemplateProject (Autotext)-Einfügen-Modul
6. Roten Text (unten) in rechtes Fenster kopieren, speichern und VBA-Editor schließen.
7. Office Symbol-Word Optionen-Anpassen-Liste Befehle auswählen: oben Makros-unten TemplateProject.ModulX.MeineBausteineDrucken auswählen-Hinzufügen klicken-Ändern wählen und Namen in „Bausteine drucken“ändern-OK-OK
8. autotext.dotm speichern und schließen
9. Symbol Dokumentvorlage auf Symbolleiste wählen- Hinzufügen klicken-Vertrauenswürdige Vorlagen-autotext.dotm-OK (Diese Verbindung wird zwar gespeichert, aber bei Neustart von Word nicht wieder hergestellt, d. h. Du musst nach Neustart das Symbol Dokumentvorlage wählen und das Häkchen setzen, wenn Du Bausteine benötigst.)
10. In beliebigem Dokument kannst Du jetzt mit dem Symbol "Autotext" Bausteine erstellen (Speichern in „autotext.dotm“) und mit Anklicken einfügen. Zum Löschen benutzt Du das Symbol "Organizer für Bausteine".
11. Drucken: Klick auf Symbol „Bausteine drucken“ druckt alle Bausteine in autotext.dotm
12. Zur Weitergabe kopierst Du die Vorlage autotext.dotm und öffnest sie auf dem anderen Rechner. Dort legst Du am besten die gleichen Symbole an wie in Schritt 2 und 7, speicherst die Vorlage in Vertrauenswürdige Vorlagen, schließt sie und stellst die Verbindung wie in Schritt 9 her.

Sub MeineBausteineDrucken()
Dim objTmp As Template
Dim objBB As BuildingBlock
Dim lngZ1 As Long
Dim lngZ2 As Long
Dim intSchleifenzaehler As Integer
Dim bytSchriftgrad As Byte
Dim lngSchriftfarbe As Long

Documents.Add

intSchleifenzaehler = 0

For lngZ1 = 1 To Templates.Count
    Set objTmp = Templates(lngZ1)

    If objTmp.Name = "autotext.dotm" Then
        For lngZ2 = 1 To objTmp.BuildingBlockEntries.Count
            Set objBB = objTmp.BuildingBlockEntries.Item(lngZ2)
           
            If objBB.Type.Name = "AutoText" Then
                bytSchriftgrad = Selection.Font.Size
                lngSchriftfarbe = Selection.Font.Color
               
                With Selection
                    With .Font
                        .Bold = True
                        .Size = 10
                        .Color = wdColorRed
                    End With
                    .TypeText Text:="Baustein: " & objBB.Name
                    .TypeParagraph
                    With .Font
                        .Bold = False
                        .Size = bytSchriftgrad
                        .Color = lngSchriftfarbe
                    End With
                    objBB.Insert .Range
                    .TypeParagraph
                    .TypeParagraph
                End With
               
                intSchleifenzaehler = intSchleifenzaehler + 1
            End If
        Next lngZ2
    End If
Next lngZ1

If intSchleifenzaehler > 0 Then
    With Selection
        .HomeKey Unit:=wdStory
        .TypeParagraph
        .MoveUp
        .Font.Bold = True
        .Font.Size = 10
        .Font.Color = wdColorRed
        .TypeText "Anzahl Bausteine: " & intSchleifenzaehler
        .TypeParagraph
        .Font.Bold = False
        .Font.Size = bytSchriftgrad
        .Font.Color = lngSchriftfarbe
    End With
Else
    Exit Sub
End If

ActiveDocument.PrintOut Range:=wdPrintAllDocument

End Sub

Viel Erfolg

Joachim